nix-dotfiles/flake.nix

{
  description = "NixOS configuration with flakes";
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";

    lix-module = {
      url = "https://git.lix.systems/lix-project/nixos-module/archive/2.91.1-2.tar.gz";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nixos-hardware.url = "github:NixOS/nixos-hardware/master";

  };
  outputs =
    {
      self,
      nixpkgs,
      lix-module,
      home-manager,
      nixos-hardware,
    }:
    let
      system = "x86_64-linux";
    in
    {
      nixosConfigurations =
        let
          dumbassFunction = { hostname, modules }:
          let
            defaultModules = [
              ./hosts/${hostname}/configuration.nix
              home-manager.nixosModules.home-manager
              lix-module.nixosModules.default
            ];
          in
          {
            name = hostname;
            value = nixpkgs.lib.nixosSystem {
              inherit system;
              modules = defaultModules ++ modules;
            };
          };
        in
        builtins.listToAttrs (
          builtins.map dumbassFunction [
            {
              hostname = "randolph";
              modules = [ nixos-hardware.nixosModules.framework-13-7040-amd ];
            }
            {
              hostname = "de-lacadie";
              modules = [];
            }
          ]
        );
    };
}